Distribution/readme2fo.xsl

   1 <?xml version="1.0" encoding="UTF-8"?>
   2 <!-- $Id$ -->
   3 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format">
   4 <!-- Need to instruct the XSLT processor to use XML output rules.
   5      See http://www.w3.org/TR/xslt#output for more details
   6 -->
   7         <xsl:output method="xml" indent="yes" encoding="UTF-8" />
   8         <xsl:param name="version" />
   9
  10         <!-- This template matches the root element of the readme document and emits the page
  11          master definitions -->
  12         <xsl:template match='readme'>
  13
  14                 <fo:root>
  15
  16
  17
  18                         <!-- We are producing A4 pages -->
  19                         <fo:layout-master-set>
  20                                 <fo:simple-page-master
  21                                         master-name="main-a4"
  22                                         page-height="297mm" page-width="210mm"
  23                                         margin-top="20mm" margin-right="30mm" margin-bottom="10mm" margin-left="20mm"
  24                                 >
  25                                         <fo:region-before extent="20mm"/>
  26                                         <fo:region-body margin-top="0mm" margin-bottom="20mm"/>
  27                                         <fo:region-after extent="10mm"/>
  28                                 </fo:simple-page-master>
  29
  30                                 <fo:page-sequence-master master-name="sequence">
  31                                         <fo:single-page-master-reference master-reference="main-a4"/>
  32                                 </fo:page-sequence-master>
  33
  34                         </fo:layout-master-set>
  35
  36
  37                         <!-- define a master page sequence. Our sequence is simple and only has
  38                              one kind of page for the entire document. -->
  39                         <fo:page-sequence master-reference="main-a4">
  40
  41
  42                                 <!-- This fo:static-content element which we are putting into the "after" section
  43                                      will create a small footer with the document title and the page number at the
  44                                      bottom of each page -->
  45                                 <fo:static-content flow-name="xsl-region-after">
  46                                 <fo:block font-family="Helvetica" font-style="italic" font-size="9pt" margin-top="10mm" color="#fff" background-color="#000" padding="1mm"><xsl:value-of select="/readme/title"/> v<xsl:value-of select="$version"/> – Page <fo:page-number/></fo:block>
  47                                 </fo:static-content>
  48
  49
  50
  51                                 <!-- This is the main and only flow which produces
  52                                      content for the pages -->
  53                                 <fo:flow flow-name="xsl-region-body">
  54                                 <xsl:apply-templates/>
  55                                 <fo:block padding-top="40mm"><fo:external-graphic src="file:///Users/liyanage/cvs/entropy/TestXSLT/TestXSLT-Icon.png"/></fo:block>
  56                                 </fo:flow>
  57
  58                         </fo:page-sequence>
  59
  60                 </fo:root>
  61
  62         </xsl:template>
  63
  64
  65
  66
  67
  68
  69
  70
  71         <!-- Following are all templates which produce XSL-FO layout elements,
  72              usually this means fo:block elements with various attributes -->
  73
  74
  75         <!-- The title is in a gray box -->
  76         <xsl:template match='title'>
  77                 <fo:block border="0.5pt" padding-top="2mm" padding-bottom="0mm" padding-left="2mm" background-color="#eeeeee" border-color="#aaaaaa" border-style="solid" margin-top="10mm" margin-left="0mm" font-size="24pt" font-family="Helvetica"  font-weight="bold" line-height="30pt">
  78                         <xsl:apply-templates/> v<xsl:value-of select="$version"/>
  79                 </fo:block>
  80         </xsl:template>
  81
  82
  83
  84
  85
  86
  87
  88         <!-- description, requirements and history all look the same because they
  89              are all introduce a top-level section -->
  90         <xsl:template match='description'>
  91                 <fo:block padding-top="8mm" font-family="Helvetica"  font-weight="bold" font-size="18pt">Description</fo:block>
  92
  93                 <xsl:call-template name="sectionrule"/>
  94                 <fo:block margin-left="15mm"><xsl:apply-templates/></fo:block>
  95
  96         </xsl:template>
  97
  98
  99         <xsl:template match='requirements'>
 100                 <fo:block padding-top="8mm" font-family="Helvetica"  font-weight="bold" font-size="18pt">Requirements</fo:block>
 101
 102                 <xsl:call-template name="sectionrule"/>
 103                 <fo:block margin-left="15mm"><xsl:call-template name="para"/></fo:block>
 104
 105         </xsl:template>
 106
 107
 108         <xsl:template match='history'>
 109                 <fo:block padding-top="8mm" font-family="Helvetica"  font-weight="bold" font-size="18pt">History</fo:block>
 110
 111                 <xsl:call-template name="sectionrule"/>
 112                 <xsl:apply-templates/>
 113         </xsl:template>
 114
 115
 116
 117
 118
 119
 120
 121         <!-- This produces a list-block item for history entries -->
 122         <xsl:template match='entry'>
 123                 <fo:block keep-with-next="always" padding-top="8mm" font-family="Helvetica" font-weight="bold" font-style="italic" font-size="11pt">Version <xsl:value-of select="version"/>, released <xsl:value-of select="date"/></fo:block>
 124
 125                 <xsl:call-template name="entryrule"/>
 126                 <fo:list-block margin-left="15mm"><xsl:apply-templates select="item"/></fo:list-block>
 127         </xsl:template>
 128
 129
 130         <xsl:template match='item'>
 131
 132                 <fo:list-item font-size="12pt" line-height="15pt">
 133                         <fo:list-item-label><fo:block padding-top="0.5mm" font-family="ZapfDingbats">&#x2794;</fo:block></fo:list-item-label>
 134                         <fo:list-item-body start-indent="body-start() - 3mm"><fo:block padding-top="0.5mm" font-family="Times"><xsl:apply-templates/></fo:block></fo:list-item-body>
 135                 </fo:list-item>
 136         </xsl:template>
 137
 138
 139
 140
 141         <!-- A 1pt-wide horizontal rule for the section headings -->
 142         <xsl:template name='sectionrule'>
 143                 <fo:block padding-top="-3mm"><fo:leader leader-length="100%" leader-pattern="rule" rule-style="solid" rule-thickness="1pt" color="black"/></fo:block>
 144         </xsl:template>
 145
 146
 147         <!-- A 1pw-wide dotted horizontal rule for history entry subheadings -->
 148         <xsl:template name='entryrule'>
 149                 <fo:block keep-with-next="always" padding-top="-3mm"><fo:leader leader-length="100%" leader-pattern="rule" rule-style="dotted" rule-thickness="1pt"/></fo:block>
 150         </xsl:template>
 151
 152
 153         <!-- Our regular paragraphs in the description section -->
 154         <xsl:template match='para' name='para'>
 155                 <fo:block padding-top="2mm" font-size="12pt" font-family="Times" line-height="15pt"><xsl:apply-templates/></fo:block>
 156
 157         </xsl:template>
 158
 159
 160         <!-- Make real, clickable URLs out of url elements -->
 161         <xsl:template match='url'>
 162 <fo:basic-link external-destination="{.}"><fo:inline color="blue"><xsl:apply-templates/></fo:inline></fo:basic-link>    </xsl:template>
 163
 164
 165         <!-- The same for email, put make them mailto: URLs -->
 166         <xsl:template match='email'>
 167
 168                 <fo:basic-link external-destination="mailto:{.}?subject=TestXSLT-Readme-PDF"><fo:inline color="blue"><xsl:apply-templates/></fo:inline></fo:basic-link>
 169         </xsl:template>
 170
 171
 172         <!-- Document authorship information -->
 173         <xsl:template match='author'>
 174
 175                 <fo:block padding-top="5mm" font-size="12pt" font-family="Times" font-weight="bold" font-style="italic"><xsl:apply-templates/></fo:block>
 176
 177         </xsl:template>
 178
 179
 180
 181
 182         <!-- The templates above should catch all content, we do not want
 183              anything to fall through. If something still does, we will paint
 184              a red border around it here so it stands out and we can fix the problem -->
 185         <xsl:template match='*'>
 186                 <fo:block border-style="solid" border-color="red" border-width="0.5pt" margin-top="10mm" font-size="10pt" font-family="Helvetica" line-height="12pt">
 187                 <xsl:apply-templates/>
 188                 </fo:block>
 189         </xsl:template>
 190
 191
 192 </xsl:stylesheet>