libiconv/libcharset/djgpp/config.sed

   1 # Additional editing of Makefiles
   2 /extrasub/,/^CEOF/ {
   3   /^CEOF$/ i\
   4 # DJGPP specific Makefile changes.\
   5   /^aliaspath * *=/s,:,";",g\
   6   /^lispdir *   *=/ c\\\\\
   7 lispdir = \\$(prefix)/gnu/emacs/site-lisp\
   8   /^docdir *    *=/s,/doc/,/gnudocs/,g\
   9   /TEXINPUTS=/s,:,";",g\
  10   /PATH=/s,:,";",g\
  11   s,config\\.h\\.in,config.h-in,g\
  12   s,\\.tab\\.c,_tab.c,g\
  13   s,\\.tab\\.h,_tab.h,g\
  14   s,\\.old\\.,_old.,g\
  15   s,libcharset\\.h\\.in,libcharset.h-in,g\
  16   s,Makefile\\.in\\.in,Makefile.in-in,g\
  17   s,Makefile\\.am\\.in,Makefile.am-in,g\
  18   /^install-info-am:/,/^$/ s,file-\\[0-9\\]\\[0-9\\],& \\$\\$file[0-9] \\$\\$file[0-9][0-9],\
  19   /^\\.y\\.c:/,/^$/ {\
  20     /\\\$(YACC)/ {\
  21       s,[       ]*&&.*$,,\
  22       a\\\\\
  23         -mv -f y_tab.c \\$*.c\\\\\
  24         -@test -f y.tab.c && mv -f y.tab.c \\$*.c\\\\\
  25         -@test -f y.tab.h && mv -f y.tab.h y_tab.h\
  26     }\
  27   }
  28 }
  29
  30 # Rename config.h.in into config.h-in
  31 /^ *CONFIG_HEADERS=/,/^EOF/ {
  32   s|"lib/config\.h|&:lib/config.h-in|
  33   s|"config\.h|&:config.h-in|
  34 }
  35
  36 # Rename iconv.h.in into iconv.h-in
  37 /^ *CONFIG_FILES=/,/^EOF/ {
  38   s|include/iconv\.h|&:include/iconv.h-in|
  39 }
  40
  41 # Replace (command) > /dev/null with `command > /dev/null`, since
  42 # parenthesized commands always return zero status in the ported Bash,
  43 # even if the named command doesn't exist
  44 # This does no longer work with autoconf 2.5, libtool 1.4 and automake 1.5.
  45 # /if ([^|;]*null/{
  46 #   s,(,`,
  47 #   s,),,
  48 #   s,;  *then,`; then,
  49 # }
  50
  51 # Replace (command) > /dev/null with `command > /dev/null`, since
  52 # parenthesized commands always return zero status in the ported Bash,
  53 # even if the named command doesn't exist
  54 /if [^{].*null/,/ then/ {
  55   /test .*null/ {
  56     s,(,,
  57     s,),,
  58   }
  59 }
  60
  61 # DOS-style absolute file names should be supported as well
  62 /\*) srcdir=/s,/\*,[\\\\/]* | [A-z]:[\\\\/]*,
  63 /\$]\*) INSTALL=/s,\[/\$\]\*,[\\\\/$]* | [A-z]:[\\\\/]*,
  64 /\$]\*) ac_rel_source=/s,\[/\$\]\*,[\\\\/$]* | [A-z]:[\\\\/]*,
  65
  66 # Switch the order of the two Sed commands, since DOS path names
  67 # could include a colon
  68 /ac_file_inputs=/s,\( -e "s%\^%\$ac_given_srcdir/%"\)\( -e "s%:% $ac_given_srcdir/%g"\),\2\1,
  69
  70 # Prevent the spliting of conftest.subs.
  71 # The sed script: conftest.subs is split into 48 or 90 lines long files.
  72 # This will produce sed scripts called conftest.s1, conftest.s2, etc.
  73 # that will not work if conftest.subs contains a multi line sed command
  74 # at line #90. In this case the first part of the sed command will be the
  75 # last line of conftest.s1 and the rest of the command will be the first lines
  76 # of conftest.s2. So both script will not work properly.
  77 # This matches the configure script produced by Autoconf 2.12
  78 /ac_max_sed_cmds=[0-9]/ s,=.*$,=`sed -n "$=" conftest.subs`,
  79 # This matches the configure script produced by Autoconf 2.14a
  80 /ac_max_sed_lines=[0-9]/ s,=.*$,=`sed -n "$=" $ac_cs_root.subs `,
  81
  82 # The following two items are changes needed for configuring
  83 # and compiling across partitions.
  84 # 1) The given srcdir value is always translated from the
  85 #    "x:" syntax into "/dev/x" syntax while we run configure.
  86 /^[     ]*-srcdir=\*.*$/ a\
  87     ac_optarg=`echo "$ac_optarg" | sed "s,^\\([A-Za-z]\\):,/dev/\\1,"`
  88 /set X `ls -Lt \$srcdir/ i\
  89    if `echo $srcdir | grep "^/dev/" - > /dev/null`; then\
  90      srcdir=`echo "$srcdir" | sed -e "s%^/dev/%%" -e "s%/%:/%"`\
  91    fi
  92
  93 #  2) We need links across partitions,
  94 #     so we will use "cp -pf" instead of "ln".
  95 /# Make a symlink if possible; otherwise try a hard link./,/EOF/ {
  96   s,;.*then, 2>/dev/null || cp -pf \$srcdir/\$ac_source \$ac_dest&,
  97 }
  98
  99 # Let libtool use _libs all the time.
 100 /objdir=/s,\.libs,_libs,